零知IDE——基于零知ESP32与DRV8833的稳定电机测速系统实现教程

eefocus_4087784

​ ✔零知开源（零知IDE）是一个专为电子初学者/电子兴趣爱好者设计的开源软硬件平台，在硬件上提供超高性价比STM32系列开发板、物联网控制板。取消了Bootloader程序烧录，让开发重心从 “配置环境” 转移到 “创意实现”，极大降低了技术门槛。零知IDE编程软件，内置上千个覆盖多场景的示例代码，支持项目源码一键下载，项目文章在线浏览。零知开源(零知IDE)平台通过软硬件协同创新，让你的创意快速转化为实物，来动手试试吧！

✔访问零知实验室，获取更多实战项目和教程资源吧！
www.lingzhilab.com

​

项目概述

        本项目基于零知 ESP32主控，搭配DRV8833 电机驱动模块和红外对射计数传感器，实现了高精度、高稳定性的电机速度测量与控制。核心功能包括：通过串口接收 PWM 指令控制电机转速，利用红外对射传感器采集电机码盘脉冲，结合定时器中断精准采样、EMA 指数加权滤波和平滑阈值处理，最终在 OLED 屏实时显示稳定的速度值（cm/s）、当前 PWM 输出和原始脉冲数

项目难点及解决方案

        问题描述1：实时脉冲数据经常出现大幅跳动

解决方案：采用ESP32的硬件定时器提供精确的1秒采样周期，同时结合指数加权移动平均（EMA）滤波算法和变化阈值检测机制，实现了速度值的稳定输出

一、硬件操作部分硬件清单[td]

组件名称	型号规格	数量	备注
主控板	零知ESP32-WROOM-32	1	核心控制器
电机驱动	DRV8833双H桥驱动模块	1	电机速度控制
传感器	红外对射计数传感器	1	脉冲检测
OLED显示屏	0.96寸I2C SSD1306	1	数据显示
直流电机	微型直流电机	1	待测对象
码盘	20格黑白码盘	1	安装于电机轴

接线方案表

        DRV8833采用5V供电确保电机驱动能力

[td]

零知 ESP32 引脚	连接器件	器件引脚	功能说明
12（MOTOR_AIN1）	DRV8833	AIN1	电机 PWM 控制引脚 1
13（MOTOR_AIN2）	DRV8833	AIN2	电机方向 / 停止控制引脚 2
14（SENSOR_PIN）	红外对射传感器	信号脚（OUT）	脉冲计数信号输入
21（SDA）	OLED1306	SDA	I2C 数据总线
22（SCL）	OLED1306	SCL	I2C 时钟总线
DRV8833 OUT1	直流电机	电机引脚 1	电机动力输出
DRV8833 OUT2	直流电机	电机引脚 2	电机动力输出

具体接线图

连接实物图

二、代码讲解部分

        代码核心在于实现了多层级的稳定性算法，下面详细解析关键部分：

硬件定时器中断

1. // ================= 硬件定时器配置 =================
   
2. hw_timer_t *speedSampleTimer = NULL;          // 速度采样定时器
   
3. volatile unsigned int timerInterruptCount = 0;// 定时器中断计数(10次=1秒)
   
4. portMUX_TYPE timerCriticalMux = portMUX_INITIALIZER_UNLOCKED; // 临界区保护锁
   
5. 
   
6. // ================= 中断服务函数 =================
   
7. /**
   
8. * @brief 红外传感器中断服务函数(上升沿触发+1ms去抖)
   
9. * 功能：过滤毛刺信号，统计有效脉冲数
   
10. */
    
11. void IRAM_ATTR infraredSensorIsr() {
    
12.   unsigned long currentIsrTime = micros();
    
13.   // 1ms去抖：两次中断间隔>1000μs→视为有效脉冲
    
14.   if (currentIsrTime - lastSensorIsrTime > 1000) {
    
15.     portENTER_CRITICAL_ISR(&timerCriticalMux); // 禁止其他中断，保护计数变量
    
16.     sensorPulseCount++;
    
17.     portEXIT_CRITICAL_ISR(&timerCriticalMux);
    
18.     lastSensorIsrTime = currentIsrTime;
    
19.   }
    
20. }
    
21. 
    
22. /**
    
23. * @brief 定时器中断服务函数(100ms触发一次)
    
24. * 功能：累计中断次数，触发1秒一次的速度计算
    
25. */
    
26. void IRAM_ATTR speedSampleTimerIsr() {
    
27.   portENTER_CRITICAL_ISR(&timerCriticalMux);
    
28.   timerInterruptCount++;
    
29.   portEXIT_CRITICAL_ISR(&timerCriticalMux);
    
30. }

复制代码

IRAM_ATTR确保中断函数存储在IRAM中，提高执行速度

硬件定时器配置

1. void setup() {
   
2.   // 串口初始化(115200波特率，用于控制和波形输出)
   
3.   Serial.begin(115200);
   
4.   while (!Serial); // 等待串口就绪(兼容部分开发板)
   
5.   
   
6.   // OLED初始化
   
7.   if (!oledDisplay.begin(SSD1306_SWITCHCAPVCC, OLED_I2C_ADDR)) {
   
8.     Serial.println("OLED Init Failed!");
   
9.     while (1); // 初始化失败则卡死，提示错误
   
10.   }
    
11.   oledDisplay.setTextColor(SSD1306_WHITE); // 设置字体颜色为白色
    
12. 
    
13.   // PWM初始化(适配DRV8833)
    
14.   ledcSetup(PWM_CHANNEL_MOTOR, PWM_FREQUENCY, PWM_RESOLUTION);
    
15.   ledcSetup(PWM_CHANNEL_STANDBY, PWM_FREQUENCY, PWM_RESOLUTION);
    
16.   ledcAttachPin(MOTOR_DRV_AIN1, PWM_CHANNEL_MOTOR);
    
17.   ledcAttachPin(MOTOR_DRV_AIN2, PWM_CHANNEL_STANDBY);
    
18. 
    
19.   // 红外传感器初始化(下拉输入+上升沿中断)
    
20.   pinMode(INFRARED_SENSOR_PIN, INPUT_PULLDOWN);
    
21.   attachInterrupt(digitalPinToInterrupt(INFRARED_SENSOR_PIN),
    
22.                   infraredSensorIsr, RISING);
    
23. 
    
24.   // 速度采样定时器初始化(100ms中断一次)
    
25.   speedSampleTimer = timerBegin(0, 80, true); // 定时器0，80分频(1MHz计数)，向上计数
    
26.   timerAttachInterrupt(speedSampleTimer, &speedSampleTimerIsr, true); // 绑定中断函数
    
27.   timerAlarmWrite(speedSampleTimer, 100000ul, true); // 100000×1μs=100ms，自动重载
    
28.   timerAlarmEnable(speedSampleTimer); // 使能定时器中断
    
29.   
    
30.   // 系统就绪提示
    
31.   Serial.println("=== System Ready ===");
    
32.   Serial.println("Usage: Send PWM value (0~255) via Serial to control motor");
    
33.   Serial.println("Serial Output Format: RawPulse | FilteredPulse | Speed(cm/s)");
    
34.   Serial.println("====================");
    
35. }

复制代码

timerBegin 使用定时器0，预分频80(80MHz/80=1MHz)，向上计数；timerAlarmWrite设置报警值为100,000微秒，自动重载；每10次中断构成1秒的完整采样周期

指数加权移动平均滤波

1. void loop() {
   
2.   // 1. 串口接收PWM指令，控制电机速度
   
3.   if (Serial.available() > 0) {
   
4.     int inputPwm = Serial.parseInt(); // 读取串口发送的PWM值
   
5.     // 验证输入有效性(仅接收0~255的数值)
   
6.     if ((Serial.read() == '\n' || Serial.read() == '\r') && inputPwm >= 0 && inputPwm <= 255) {
   
7.       setMotorPwmSpeed(inputPwm);
   
8.       Serial.printf("Motor PWM Set to: %d\n", currentMotorPwm);
   
9.     } else {
   
10.       Serial.println("Invalid Input! Please send number between 0~255");
    
11.     }
    
12.   }
    
13. 
    
14.   // 2. 每1秒采样一次，计算稳定速度(定时器中断累计10次=1秒)
    
15.   if (timerInterruptCount >= 10) {
    
16.     portENTER_CRITICAL(&timerCriticalMux); // 临界区保护，避免数据冲突
    
17.     unsigned long rawPulse = sensorPulseCount; // 读取原始脉冲数
    
18.     sensorPulseCount = 0;                      // 重置脉冲计数
    
19.     timerInterruptCount = 0;                   // 重置定时器计数
    
20.     portEXIT_CRITICAL(&timerCriticalMux);
    
21. 
    
22.     // --- 核心算法：数据平滑+稳定速度计算 ---
    
23.     // A. 静态噪声过滤：低速截止
    
24.     if (rawPulse < minValidPulse) {
    
25.       rawPulse = 0;
    
26.       filteredPulseCount = 0.0; // 强制归零，避免噪声导致的虚假速度
    
27.     }
    
28. 
    
29.     // B. EMA指数加权滤波：平滑原始脉冲数据
    
30.     // 公式：滤波后值 = α×当前测量值 + (1-α)×上一次滤波值
    
31.     filteredPulseCount = (emaFilterAlpha * rawPulse) + ((1.0 - emaFilterAlpha) * filteredPulseCount);
    
32. 
    
33.     // C. 阈值判断：仅当脉冲变化足够大时更新显示(抑制微小波动)
    
34.     if (abs(filteredPulseCount - lastDisplayedPulse) > speedUpdateThreshold || rawPulse == 0) {
    
35.       lastDisplayedPulse = filteredPulseCount; // 更新显示用脉冲数
    
36.     }
    
37. 
    
38.     // D. 计算最终稳定速度(cm/s)
    
39.     currentSpeedCmS = lastDisplayedPulse * cmPerPulse;
    
40. 
    
41.     // --- 串口输出(格式固定，适配波形工具) ---
    
42.     // 输出格式：Raw脉冲数 | 滤波后脉冲数 | 速度(cm/s)，保留2位小数
    
43.     Serial.print(rawPulse);
    
44.     Serial.print(" | ");
    
45.     Serial.print(filteredPulseCount, 1); // 滤波后脉冲数保留1位小数
    
46.     Serial.print(" | ");
    
47.     Serial.println(currentSpeedCmS, 2); // 速度保留2位小数，波形更细腻
    
48. 
    
49.     // --- 更新OLED显示 ---
    
50.     updateOledDisplay(lastDisplayedPulse, currentSpeedCmS);
    
51.   }
    
52. }

复制代码

[td]

环节	输入	输出	核心作用
低速截止	原始脉冲数	0 或原始值	过滤静态噪声（无电机转动时的误计数）
EMA 滤波	原始脉冲数 / 上次平滑值	平滑后脉冲数	抑制大幅波动，保留趋势
变化阈值	平滑后脉冲数 / 上次显示值	稳定显示值	过滤 ±1~2 的微小波动，保持显示稳定

项目完整代码

1. /**************************************************************************************
   
2. 文件: /DRV8833_Motor_Stable_Speed/DRV8833_Motor_Stable_Speed.ino
   
3. 作者：零知实验室（深圳市在芯间科技有限公司）
   
4. -^^- 零知开源，让电子制作变得更简单！ -^^-
   
5. 时间: 2025-12-2 16:36:27
   
6. 说明: 基于ESP32的电机稳速测速系统。通过红外传感器检测脉冲，结合EMA滤波和阈值算法计算稳定速度，并在OLED上实时显示。可通过串口调节电机PWM速度。
   
7. ***************************************************************************************/
   
8. 
   
9. #include <Wire.h>
   
10. #include <Adafruit_GFX.h>
    
11. #include <Adafruit_SSD1306.h>
    
12. 
    
13. // ================= 用户可调参数 (校准区) =================
    
14. // 1. 脉冲-距离转换系数 (cm/脉冲)：根据实际硬件校准
    
15. // 理论计算: 轮径25.75mm × π ÷ 码盘20格 ≈ 0.4045 cm/脉冲
    
16. // 校准规则：测量距离偏短→增大；偏长→减小
    
17. float cmPerPulse = 0.4045;
    
18. 
    
19. // 2. EMA滤波平滑系数 (0.01~1.0)
    
20. // 小值→更平滑但响应慢；大值→响应快但抖动大
    
21. const float emaFilterAlpha = 0.3;
    
22. 
    
23. // 3. 速度更新阈值 (死区)：抑制微小波动
    
24. // 仅当脉冲变化超过此值时更新显示，避免数值频繁跳动
    
25. const float speedUpdateThreshold = 2.0;
    
26. 
    
27. // 4. 最小有效脉冲数：过滤静态噪声
    
28. // 1秒内脉冲数小于此值→视为电机停止
    
29. const int minValidPulse = 2;
    
30. 
    
31. // ================= 硬件引脚定义 =================
    
32. #define OLED_SCREEN_WIDTH 128    // OLED屏幕宽度
    
33. #define OLED_SCREEN_HEIGHT 64    // OLED屏幕高度
    
34. #define OLED_I2C_ADDR 0x3C       // OLED默认I2C地址
    
35. Adafruit_SSD1306 oledDisplay(OLED_SCREEN_WIDTH, OLED_SCREEN_HEIGHT, &Wire, -1);
    
36. 
    
37. // DRV8833电机驱动引脚
    
38. #define MOTOR_DRV_AIN1 12        // 电机PWM控制引脚1
    
39. #define MOTOR_DRV_AIN2 13        // 电机方向/停止控制引脚2
    
40. #define INFRARED_SENSOR_PIN 14   // 红外对射传感器信号引脚
    
41. 
    
42. // ESP32 PWM配置参数
    
43. #define PWM_CHANNEL_MOTOR 0      // 电机PWM通道1
    
44. #define PWM_CHANNEL_STANDBY 1    // 电机备用通道2
    
45. #define PWM_RESOLUTION 8         // PWM分辨率(8位→0~255)
    
46. #define PWM_FREQUENCY 1000       // PWM频率(1kHz，适配DRV8833)
    
47. 
    
48. // ================= 全局变量 =================
    
49. volatile unsigned long sensorPulseCount = 0;   // 传感器原始脉冲计数
    
50. volatile unsigned long lastSensorIsrTime = 0;  // 传感器中断上次触发时间(去抖用)
    
51. 
    
52. // 滤波后数据存储
    
53. float filteredPulseCount = 0.0;    // EMA滤波后的脉冲数
    
54. float currentSpeedCmS = 0.0;       // 当前稳定速度(cm/s)
    
55. float lastDisplayedPulse = 0.0;    // 上一次显示的脉冲数
    
56. 
    
57. int currentMotorPwm = 0;           // 当前电机PWM输出值
    
58. 
    
59. // ================= 硬件定时器配置 =================
    
60. hw_timer_t *speedSampleTimer = NULL;          // 速度采样定时器
    
61. volatile unsigned int timerInterruptCount = 0;// 定时器中断计数(10次=1秒)
    
62. portMUX_TYPE timerCriticalMux = portMUX_INITIALIZER_UNLOCKED; // 临界区保护锁
    
63. 
    
64. // ================= 中断服务函数 =================
    
65. /**
    
66. * @brief 红外传感器中断服务函数(上升沿触发+1ms去抖)
    
67. * 功能：过滤毛刺信号，统计有效脉冲数
    
68. */
    
69. void IRAM_ATTR infraredSensorIsr() {
    
70.   unsigned long currentIsrTime = micros();
    
71.   // 1ms去抖：两次中断间隔>1000μs→视为有效脉冲
    
72.   if (currentIsrTime - lastSensorIsrTime > 1000) {
    
73.     portENTER_CRITICAL_ISR(&timerCriticalMux); // 禁止其他中断，保护计数变量
    
74.     sensorPulseCount++;
    
75.     portEXIT_CRITICAL_ISR(&timerCriticalMux);
    
76.     lastSensorIsrTime = currentIsrTime;
    
77.   }
    
78. }
    
79. 
    
80. /**
    
81. * @brief 定时器中断服务函数(100ms触发一次)
    
82. * 功能：累计中断次数，触发1秒一次的速度计算
    
83. */
    
84. void IRAM_ATTR speedSampleTimerIsr() {
    
85.   portENTER_CRITICAL_ISR(&timerCriticalMux);
    
86.   timerInterruptCount++;
    
87.   portEXIT_CRITICAL_ISR(&timerCriticalMux);
    
88. }
    
89. 
    
90. // ================= 辅助函数 =================
    
91. /**
    
92. * @brief 设置电机PWM速度
    
93. * @param pwmVal: PWM值(0~255)，0→停止，越大转速越快
    
94. */
    
95. void setMotorPwmSpeed(int pwmVal) {
    
96.   currentMotorPwm = constrain(pwmVal, 0, 255); // 限制PWM范围(0~255)
    
97.   if (currentMotorPwm == 0) {
    
98.     ledcWrite(PWM_CHANNEL_MOTOR, 0);
    
99.     ledcWrite(PWM_CHANNEL_STANDBY, 0); // 两通道均为0→电机停止
    
100.   } else {
     
101.     ledcWrite(PWM_CHANNEL_MOTOR, currentMotorPwm);
     
102.     ledcWrite(PWM_CHANNEL_STANDBY, 0); // DRV8833正转模式
     
103.   }
     
104. }
     
105. 
     
106. /**
     
107. * @brief 更新OLED显示内容
     
108. * @param dispPulse: 显示用脉冲数(滤波后)
     
109. * @param dispSpeed: 显示用速度(cm/s)
     
110. */
     
111. void updateOledDisplay(float dispPulse, float dispSpeed) {
     
112.   oledDisplay.clearDisplay();
     
113.   
     
114.   // 标题栏
     
115.   oledDisplay.setTextSize(1);
     
116.   oledDisplay.setCursor(0, 0);
     
117.   oledDisplay.println("STABLE SPEED METER");
     
118.   oledDisplay.drawLine(0, 10, OLED_SCREEN_WIDTH, 10, SSD1306_WHITE);
     
119. 
     
120.   // 速度显示(大号字体)
     
121.   oledDisplay.setCursor(0, 20);
     
122.   oledDisplay.setTextSize(2);
     
123.   oledDisplay.print(dispSpeed, 2); // 保留2位小数，提高精度
     
124.   oledDisplay.setTextSize(1);
     
125.   oledDisplay.println(" cm/s");
     
126. 
     
127.   // 辅助信息(PWM+脉冲数)
     
128.   oledDisplay.setCursor(0, 45);
     
129.   oledDisplay.print("PWM: "); oledDisplay.print(currentMotorPwm);
     
130.   
     
131.   oledDisplay.setCursor(64, 45);
     
132.   oledDisplay.print("Pulse: "); oledDisplay.print((int)dispPulse);
     
133. 
     
134.   oledDisplay.display();
     
135. }
     
136. 
     
137. // ================= 初始化函数 =================
     
138. void setup() {
     
139.   // 串口初始化(115200波特率，用于控制和波形输出)
     
140.   Serial.begin(115200);
     
141.   while (!Serial); // 等待串口就绪(兼容部分开发板)
     
142.   
     
143.   // OLED初始化
     
144.   if (!oledDisplay.begin(SSD1306_SWITCHCAPVCC, OLED_I2C_ADDR)) {
     
145.     Serial.println("OLED Init Failed!");
     
146.     while (1); // 初始化失败则卡死，提示错误
     
147.   }
     
148.   oledDisplay.setTextColor(SSD1306_WHITE); // 设置字体颜色为白色
     
149. 
     
150.   // PWM初始化(适配DRV8833)
     
151.   ledcSetup(PWM_CHANNEL_MOTOR, PWM_FREQUENCY, PWM_RESOLUTION);
     
152.   ledcSetup(PWM_CHANNEL_STANDBY, PWM_FREQUENCY, PWM_RESOLUTION);
     
153.   ledcAttachPin(MOTOR_DRV_AIN1, PWM_CHANNEL_MOTOR);
     
154.   ledcAttachPin(MOTOR_DRV_AIN2, PWM_CHANNEL_STANDBY);
     
155. 
     
156.   // 红外传感器初始化(下拉输入+上升沿中断)
     
157.   pinMode(INFRARED_SENSOR_PIN, INPUT_PULLDOWN);
     
158.   attachInterrupt(digitalPinToInterrupt(INFRARED_SENSOR_PIN),
     
159.                   infraredSensorIsr, RISING);
     
160. 
     
161.   // 速度采样定时器初始化(100ms中断一次)
     
162.   speedSampleTimer = timerBegin(0, 80, true); // 定时器0，80分频(1MHz计数)，向上计数
     
163.   timerAttachInterrupt(speedSampleTimer, &speedSampleTimerIsr, true); // 绑定中断函数
     
164.   timerAlarmWrite(speedSampleTimer, 100000ul, true); // 100000×1μs=100ms，自动重载
     
165.   timerAlarmEnable(speedSampleTimer); // 使能定时器中断
     
166.   
     
167.   // 系统就绪提示
     
168.   Serial.println("=== System Ready ===");
     
169.   Serial.println("Usage: Send PWM value (0~255) via Serial to control motor");
     
170.   Serial.println("Serial Output Format: RawPulse | FilteredPulse | Speed(cm/s)");
     
171.   Serial.println("====================");
     
172. }
     
173. 
     
174. // ================= 主循环 =================
     
175. void loop() {
     
176.   // 1. 串口接收PWM指令，控制电机速度
     
177.   if (Serial.available() > 0) {
     
178.     int inputPwm = Serial.parseInt(); // 读取串口发送的PWM值
     
179.     // 验证输入有效性(仅接收0~255的数值)
     
180.     if ((Serial.read() == '\n' || Serial.read() == '\r') && inputPwm >= 0 && inputPwm <= 255) {
     
181.       setMotorPwmSpeed(inputPwm);
     
182.       Serial.printf("Motor PWM Set to: %d\n", currentMotorPwm);
     
183.     } else {
     
184.       Serial.println("Invalid Input! Please send number between 0~255");
     
185.     }
     
186.   }
     
187. 
     
188.   // 2. 每1秒采样一次，计算稳定速度(定时器中断累计10次=1秒)
     
189.   if (timerInterruptCount >= 10) {
     
190.     portENTER_CRITICAL(&timerCriticalMux); // 临界区保护，避免数据冲突
     
191.     unsigned long rawPulse = sensorPulseCount; // 读取原始脉冲数
     
192.     sensorPulseCount = 0;                      // 重置脉冲计数
     
193.     timerInterruptCount = 0;                   // 重置定时器计数
     
194.     portEXIT_CRITICAL(&timerCriticalMux);
     
195. 
     
196.     // --- 核心算法：数据平滑+稳定速度计算 ---
     
197.     // A. 静态噪声过滤：低速截止
     
198.     if (rawPulse < minValidPulse) {
     
199.       rawPulse = 0;
     
200.       filteredPulseCount = 0.0; // 强制归零，避免噪声导致的虚假速度
     
201.     }
     
202. 
     
203.     // B. EMA指数加权滤波：平滑原始脉冲数据
     
204.     // 公式：滤波后值 = α×当前测量值 + (1-α)×上一次滤波值
     
205.     filteredPulseCount = (emaFilterAlpha * rawPulse) + ((1.0 - emaFilterAlpha) * filteredPulseCount);
     
206. 
     
207.     // C. 阈值判断：仅当脉冲变化足够大时更新显示(抑制微小波动)
     
208.     if (abs(filteredPulseCount - lastDisplayedPulse) > speedUpdateThreshold || rawPulse == 0) {
     
209.       lastDisplayedPulse = filteredPulseCount; // 更新显示用脉冲数
     
210.     }
     
211. 
     
212.     // D. 计算最终稳定速度(cm/s)
     
213.     currentSpeedCmS = lastDisplayedPulse * cmPerPulse;
     
214. 
     
215.     // --- 串口输出(格式固定，适配波形工具) ---
     
216.     // 输出格式：Raw脉冲数 | 滤波后脉冲数 | 速度(cm/s)，保留2位小数
     
217.     Serial.print(rawPulse);
     
218.     Serial.print(" | ");
     
219.     Serial.print(filteredPulseCount, 1); // 滤波后脉冲数保留1位小数
     
220.     Serial.print(" | ");
     
221.     Serial.println(currentSpeedCmS, 2); // 速度保留2位小数，波形更细腻
     
222. 
     
223.     // --- 更新OLED显示 ---
     
224.     updateOledDisplay(lastDisplayedPulse, currentSpeedCmS);
     
225.   }
     
226. }

复制代码

系统流程图

三、项目结果演示校准全过程1）硬件安装与接线

        按接线表连接所有器件，确保：

红外对射传感器与码盘间距 5~10mm，对齐齿隙；DRV8833 供电电压匹配电机；OLED I2C 地址为 0x3C
2）传统 PID 方案测试

        烧录原始 PID 代码，打开OLED 显示屏上的局域网地址，观察脉冲波形变化

原始脉冲数波动 52~71，抖动严重，无法稳定显示
3）改进方案校准

        烧录改进后代码，进行以下校准：

距离校准（CM_PER_PULSE）：
        ①用尺子量取 1 米（100cm）距离，在串口发送 PWM=150，让电机带动轮子沿直线走 1 米；
        ②记录串口打印的Raw值（假设为 247），则CM_PER_PULSE=100/247≈0.405，修改代码后重新上传
滤波系数调节（FILTER_ALPHA）：
        若速度仍抖，减小 α（如 0.2）；若响应过慢，增大 α（如 0.4）
阈值调节（CHANGE_THRESHOLD）：
        微小波动多则增大至 2.5~3.0；响应迟缓则减小至 1.5~2.0
4）稳定测试

        发送不同 PWM 值（50~255），观察串口和 OLED：

串口打印：Raw 值波动 ±3~5，但 Filtered 值波动≤±1，DispSpeed 波动≤±0.3 cm/s；
OLED 显示：速度值稳定，无频繁跳变

参数调节指南[td]

参数	默认值	调节范围	作用	调节建议
CM_PER_PULSE	0.4045	0.1-1.0	每个脉冲对应的距离	根据实际测量校准
FILTER_ALPHA	0.3	0.01-1.0	滤波平滑系数	值越小越平滑但响应慢
CHANGE_THRESHOLD	2.0	0.5-10.0	变化检测阈值	值越大显示越稳定
MIN_PULSE_CUTOFF	2	1-10	最小有效脉冲	过滤静止噪声

稳定速度输出波形图

打开调试功能/串口绘图仪→设置波特率→观察波形脉冲和速度变化：

速度波形基本呈水平线，波动幅度≤±0.3 cm/s，无大幅跳变

视频演示

https://live.csdn.net/v/504219?spm=1001.2014.3001.5501

串口发送 PWM 指令（255→127→90→0）、实时展示 OLED 屏，速度值稳定更新，PWM 与原始脉冲数同步显示、串口波形区速度波形平稳，无剧烈波动

四、DRV8833 与红外对射传感器技术讲解DRV8833 电机驱动模块工作原理

        DRV8833 内部集成双 H 桥驱动电路，H 桥由 4 个 MOS 管组成，通过控制 MOS 管的导通 / 截止实现电机正转、反转、停止和调速

正转：AIN1=PWM，AIN2=LOW；
反转：AIN1=LOW，AIN2=PWM；
停止：AIN1=LOW，AIN2=LOW；
调速：改变 PWM 占空比（0~255），占空比越大，电机转速越高

红外对射计数传感器工作原理

传感器由红外发射管和接收管组成，呈对射式安装：

        无遮挡时：发射管发出的红外光被接收管接收，接收管导通，输出低电平；有遮挡时（码盘齿经过）：红外光被阻断，接收管截止，输出高电平；电机转动时，码盘的齿和间隙交替遮挡红外光，传感器输出连续脉冲，脉冲数 = 码盘齿数 × 转动圈数。
计数逻辑

本项目电机码盘为 20 格（20 齿 + 20 间隙），电机转 1 圈，传感器输出 20 个脉冲；结合轮径计算每脉冲对应的距离：

每脉冲距离（cm）= 轮子周长（cm）/ 码盘齿数 =（π×轮径cm）/20

​ 五、常见问题解答（FAQ）Q1：为什么我的脉冲计数仍然不稳定？

        A：请按以下步骤排查：检查传感器安装是否牢固，码盘是否偏心；测量传感器输出信号，增大 FILTER_ALPHA 至 0.4~0.5，或增大 CHANGE_THRESHOLD 至 2.5~3.0，尝试更小的值（如0.2）；检查电源稳定性

Q2：电机不转动

        A：请检查： DRV8833 供电，确保供电电大于等于电机工作电压； PWM 值大于等于70，电机启动需要最小电压驱动；DRV8833 模块引脚的 OUT1/OUT2 正确连接到电机，，AIN1=12，AIN2=13

项目资源整合
        DRV8833数据手册：    DRV8833 Dual H-Bridge Motor Driver datasheet (Rev. E)
        OLED SSD1306库文件：    Adafruit_SSD1306