I2C总线定义I2C(‘intel’ -Integrated Circuit)总线是一种由PHILIPS公司开发的两线式串行总线,用于连接微控制器及其外围设备。在主从通信中,可以有多个I2C总线器件同时接到I2C总线上,通过地址来识别通信对象。

    I2C总线是由数据线SDA和时钟SCL构成的串行总线,可发送和接收数据。在CPU与被控IC之间、IC与IC之间进行双向传送,最高传送速率100kbps。各种被控制电路均并联在这条总线上,但就像电话机一样只有拨通各自的号码才能工作,所以每个电路和模块都有唯一的地址,在信息的传输过程中,I2C总线上并接的每一模块电路既可以是主控器(或被控器),又可以是发送器(或接收器),这取决于它所要完成的功能。

    Arduino通讯命令见网址https://www.arduino.cc/en/Reference/Wire,我通过这次IIC通讯实验把这10个I2C通讯命令全部应用到了。

    我现在采用老版本A rduino-0018编程,老版本I2C通讯的发送数据命令是send(),接受数据命令是receive(),最新版本Arduino 1.0的发送数据的命令是write(),接受数据的命令是read(),这一点要注意啊,看清楚自己下载应用的是什么版本的Arduino编程软件。Arduino程序下载地址:https://arduino.cc/en/Main/Software

     I2C实验说明: 主机向从机循环发送字符串"light is "和字节x,x为1或0,从机接收后,把数据显示在它的串口监视器中,如上图。然后当主机通知从机向它上传数据时,会把x值再上传回主机,然后赋值给变量c。当主机程序判断c为1,则点亮主机数字端口13相连的LED,否则熄灭LED。

    通过这个实验把主从机之间的双向通讯都诠释出来了。

实验全景图:

    把双Arduino控制器的SCL和SDA以及GND三根引脚用杜邦线相连,如果不是两个Arduino分别独立供电,您就要把双Arduino控制器的VCC也连一起,它们共用一个电源。这次实验就是把这四根线SCL和SDA以及GND、VCC都互连起来了。Arduino的SCL引脚位于模拟端口5,SDA引脚位于模拟端口4。

   Arduino控制器源于DFRobot官方网址:https://item.taobao.com/item.htm?spm=1101*r1F.1-1mJ7T.3-1MYgQs&id=3136612323

注意:由于“单三角括号”里的内容,博客里显示不出来,所以我把头文件声明命令“被迫”进行了修改,以便在博客里看到头文件,例如改成"#include 《Wire.h>"。

Arduino主机程序:(与I2C通讯相关的命令用蓝色标注)

 /*主机向从机循环发送字符串"light is "和字节x,x为1或0

从机接收到主机发来的数据后,当主机通知从机向它上传数据时
会把x值再上传回主机,然后赋值给变量c。
当主机程序判断c为1,则点亮LED,否则熄灭LED。*/
#include 《Wire.h>//声明I2C库文件
#define LED 13
byte x = 0;//变量x决定LED的亮灭
//初始化
void setup()
{
  Wire.begin(); // 加入 i2c 总线,作为主机
  pinMode(LED,OUTPUT);//设置数字端口13为输出
}
//主程序
void loop()
{
  Wire.beginTransmission(4); //发送数据到设备号为4的从机
  Wire.send("light is ");        // 发送字符串"light is "
  Wire.send(x);              // 发送变量x中的一个字节  
  Wire.endTransmission();    // 停止发送

  x++;//变量x加1
  if(x==2)//如果变量x的值为2,则把x值转为0
  x=0;
  delay(1000);//延时1s
  
  Wire.requestFrom(4, 1);    //通知4号从机上传1个字节
  while(Wire.available()>0)    // 当主机接收到从机数据时
  { 
    byte c = Wire.receive(); //接收一个字节赋值给c
    //判断c为1,则点亮LED,否则熄灭LED。
    if(c==1)
    {digitalWrite(LED,LOW);}
    else
     {digitalWrite(LED,HIGH);}
  }
  delay(1000);//延时1s
}
 
Arduino从机程序:(与I2C通讯相关的命令用蓝色标注)
/*循环接收主机发送来的数据包,同时显示在串口监视器上
 
把数据包的最后一个字节,再上传回主机
*/
#include 《Wire.h>//声明I2C库文件
int x;//变量x值决定主机的LED是否点亮
//初始化
void setup()
{
  Wire.begin(4);                // 加入 i2c 总线,设置从机地址为 #4
  Wire.onReceive(receiveEvent); //注册接收到主机字符的事件
  Wire.onRequest(requestEvent); // 注册主机通知从机上传数据的事件
  Serial.begin(9600);           //设置串口波特率
}
//主程序
void loop()
{
  delay(100);//延时
}

// 当从机接收到主机字符,执行该事件
void receiveEvent(int howMany)
{
  while( Wire.available()>1) // 循环执行,直到数据包只剩下最后一个字符
  {
    char c = Wire.receive(); // 作为字符接收字节
    Serial.print(c);         // 把字符打印到串口监视器中
  }
   //接收主机发送的数据包中的最后一个字节
  x = Wire.receive();    // 作为整数接收字节
  Serial.println(x);    //把整数打印到串口监视器中,并回车 
}

//当主机通知从机上传数据,执行该事件
void requestEvent()
{
  //把接收主机发送的数据包中的最后一个字节再上传给主机
  Wire.send( x); // 响应主机的通知,向主机发送一个字节数据
}
   我通过这次I2C通讯实验把这10个Arduino的I2C通讯命令全部应用到了,仔细看实验程序注释,并实践一次,就可以了解这Arduino控制器的I2C命令如何应用了。
 
源程序请下载:程序.zip
 
    在数字通信各种协议中,相对Ethernet, USB, SATA, PCI-Express等传输速度达数百上千兆字节每秒的总线,I2C和SPI常称为“小”协议。但是,我们不能忘记的是各种总线的用途是什么。“大”协议是用于系统外的整个系统之间通信的,“小”协议是用于系统内各芯片间的通信,没有迹象表明“大”协议有必要取代“小”协议。I2C和SPI的存在和流行体现了“够用就好”的哲学。